Monitoring Suhu dan Kelembapan Pake DHT11 dan Blynk via Wifi di Wemos D1 Mini

Halo teman-teman, selamat datang di website Cosmo. di artikel ini kita akan belajar monitoring suhu dan kelembapan pakai DHT11 dengan Blynk via wifi menggunakan wemos D1 Mini. untuk tutorial lengkapnya bisa di lihat pada video berikut.

Tutorial Video

Rangkaian

Penjelasan rangkaian

VCC --> kaki positif DHT11

D2 --> pin data/out DHT11

GND --> kaki negatif DHT11

Kode program

//ganti 3 baris kode di bawah ini dengan punya kalian masing-masing
#define BLYNK_TEMPLATE_ID "..."
#define BLYNK_TEMPLATE_NAME "..."
#define BLYNK_AUTH_TOKEN "..."

#define BLYNK_PRINT Serial
#include <ESP8266WiFi.h>
#include <BlynkSimpleEsp8266.h>
#include <DHT.h>


const char* ssid = "ssid wifimu";
const char* pass = "password wifimu";

#define DHTPIN D3      // Pin DHT11 pada Wemos D1 Mini
#define DHTTYPE DHT11  // Tipe sensor DHT

DHT dht(DHTPIN, DHTTYPE);
BlynkTimer timer;

void sendSensorData() {
  float temperature = dht.readTemperature();
  float humidity = dht.readHumidity();

  if (!isnan(temperature) && !isnan(humidity)) {
    Serial.print("Suhu: ");
    Serial.print(temperature);
    Serial.print(" °C, Kelembaban: ");
    Serial.print(humidity);
    Serial.println(" %");

    Blynk.virtualWrite(V1, temperature);  // Kirim suhu ke Virtual Pin V1
    Blynk.virtualWrite(V2, humidity);     // Kirim kelembaban ke Virtual Pin V2
  } else {
    Serial.println("Gagal membaca data dari DHT11!");
  }
}

void setup() {
  Serial.begin(9600);
  Blynk.begin(BLYNK_AUTH_TOKEN, ssid, pass);
  dht.begin();
  timer.setInterval(5000L, sendSensorData);  // Kirim data setiap 5 detik
}

void loop() {
  Blynk.run();
  timer.run();
}

Penjelasan Kode

Kode ini berfungsi untuk memantau suhu dan kelembapan menggunakan sensor DHT11 yang terhubung ke Wemos D1 Mini, lalu mengirimkan data ke Blynk via Wi-Fi setiap 5 detik. Pertama, kode menginisialisasi koneksi Wi-Fi dan autentikasi Blynk, lalu membaca data suhu dan kelembapan menggunakan library DHT. Data tersebut ditampilkan di Serial Monitor dan dikirim ke Virtual Pin V1 untuk suhu dan V2 untuk kelembapan di aplikasi Blynk. Loop utama menjalankan Blynk dan timer agar pengiriman data berjalan otomatis tanpa menghambat eksekusi kode lainnya. Jika ada fitur tambahan yang ingin diterapkan, kode ini bisa dikembangkan lebih lanjut.

Itu saja teman-teman, semoga video, rangkaian dan kodenya membantu proses pengerjaan proyek kalian. Jangan lupa kunjungi channel Youtube IQ+ untuk tutorial-tutorial video IoT lainnya. Jika ada masukan dan saran, silakan sampaikan melalui form di bawah. Sampai jumpa!